Pet related:


# show Prowl
/cast Freezing Trap
/use Filtered Draenic Wate/use Sunspring Carp
/cast Shadowmeld
/cast Prowl

What it does?
1. Drop Frost Trap
2. Eat/Drink (need to specify the items)
3. Shadowmeld/Prowl you and your Cat


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [nopet] Call Pet;[target=pet,dead]Revive Pet
/clearfocus [target=focus,dead]
/focus [target=focus,exists]player;target
/clearfocus [target=focus,noharm]
/petattack [target=focus,exists]
/petfollow [target=focus,noexists]
/cast Hunter's Mark

What it does?
1. If your pet is dead: You will cast Revive Pet
2. If your pet is not summoned: You will cast Call Pet.
3. If you are not focused: You will focus on your target and your pet will be sent to attack it.
4. If you are focused: You will clear focus and your pet will be recalled to follow you.
5. Hunter's Mark will be cast on the target


----------------------------------------------------------------------------------------------------------------------------------------------


/cast [nocombat] Feed Pet; [combat] Mend Pet
/use [nocombat] <food item>

(feed food by name)


OR

/cast [combat] Mend Pet; [nocombat] Feed Pet
/use [nocombat] 1 13

(Feed by bag slot: bag #1 slot #13)


OR

/cast [pet, nocombat] Feed Pet
/use [pet:Cat/Ravager, nocombat] <food item>; [pet:Wind Serpent, nocombat] <food item>

(Feed a certain food item depending on the type of pet)


OR

#show <food item>
/cast [modifier:alt][combat] Mend Pet; [pet, nocombat] Feed Pet
/use [pet, nocombat, nomodifier:alt] <food item>

(Hold down alt to cast Mend Pet out of combat, and shows the amount of food you have in your bags)


---------------------------------------------------------------------------------------------------------------------------------------------


/focus [target=pettarget,modifier:shift]
/petfollow [nomodifier:shift]
/petattack
/target [modifier:shift] focus
/petattack [modifier:shift]


What it does?
This acts like a normal pet attack button, but when you hold shift and use it, your pet will attack your current target only once it is done killing all its already queued targets.


OR


/focus [target=pettarget,modifier:shift]
/petfollow [nomodifier:shift]
/petattack [target=mouseover,modifier:shift]
/petattack
/target [modifier:shift] focus
/petattack [modifier:shift]


What it does?
Activates the queue with a simple mouseover of the next target you wish your pet to attack.
This saves you from changing between targets while shooting down another mob.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; Mend Pet


What it does?
This will revive your pet if it's dead, call your pet if you don't have him out, or mend your pet.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [nopet] Call Pet; Revive Pet


What it does?
This macro will call your pet if you do not have one, otherwise it attempts to cast Revive Pet.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [nopet,modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; [combat][modifier]Mend Pet
/stopmacro [combat]
#showtooltip Feed Pet
/cast Feed Pet
/use <food item>


OR reversed one:


#showtooltip [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [mod] <Pet Food Name>; Mend Pet
/cast [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [modifier] Feed Pet; Mend Pet
/use [modifier] <Pet Food Name>



What it does?
1. This macro calls your pet if he's not out.
2. Revives him if he's dead.
3. Heals him during combat.
4. Feeds him out of combat.
Since the macro system can't tell whether your pet is alive if his corpse isn't around, holding any modifier when you have no pet out will cast Revive Pet. Also, holding any modifier key when your pet is out will heal him instead of feeding.


---------------------------------------------------------------------------------------------------------------------------------------------


/castsequence reset=15 Mend Pet, null


What it does?
1. This macro will cast Mend Pet, but only if it has not been used in the last 15 seconds.
2. Effectively it will avoid waste of mana from accidentally casting one Mend Pet over the other.
3. If you bind it to a button, the button will be greyed out while the macro is in "hold mode".


OR


#showtooltip
/cast [modifier:shift] Mend Pet(Rank 1); Mend Pet


What it does?
This macro provides one button for those Hunters with the Improved Mend Pet talent.
Often, you will want to simply dispel your pet, rather than spend the mana of a full Mend Pet.
This macro will cast your highest rank Mend Pet by default, and cast rank 1 if holding down the shift key (Feel free to change the key to your liking).

Shots


#showtooltip Steady Shot
/castrandom [target=pettarget,exists] Kill Command
/castsequence reset=2/target !Auto Shot, Steady Shot
/script UIErrorsFrame:Clear();


OR


/cast !Auto shot
/cast Steady Shot
/cast [target=pettarget, exists] Kill Command
/script UIErrorsFrame:Clear()


What it does?
1. This macro will cast Auto Shot and Steady Shot in alternating order.
2. Preventing players from accidentally clipping Auto Shots while attempting to cast Steady Shot.
To do this, you must spam this macro, or press it repeatedly and constantly.
3. The sequence will reset after obtaining a new target or after two seconds of idle time.
4. It will also cast Kill Command every time it's up, excellent now that it is both off the global cooldown and will not push back Auto Shot.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Steady Shot
/castrandom [target=pettarget,exists] Kill Command
/cast [target=pettarget,exists] Lightning Breath
/castsequence reset=2/target !Auto Shot, Steady Shot
/script UIErrorsFrame:Clear();


What it does?
Same as above one but with Wind Serpent's Lightning Breath


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Steady Shot
/castsequence reset=120 Bladefist's Breadth,Ancient Draenei War Talisman
/cast [target=pettarget,nodead,exists] Kill Command
/castsequence reset=2/target !Auto Shot, Steady Shot


What it does?
Autocast your DPS trinkets to maximize your damage output (remeber to change the names and order for your trinkets)


---------------------------------------------------------------------------------------------------------------------------------------------


/castsequence [nocombat] Aimed Shot; [combat] reset=6 Arcane Shot, Steady Shot, Steady Shot, Steady Shot


What it does?
This macro is designed to maximize your single target ranged DPS.
It rotates through Aimed Shot, Arcane Shot, and Steady Shot.
It casts Aimed Shot if you are out of combat to start off the fight; then it casts Arcane Shot when it isn't on cooldown and Steady Shot the rest of the time.
Since three Steady Shots should take longer to cast than Arcane's cooldown, this macro will work, save haste effects like Rapid Fire or Bloodlust or Heroism.
Selecting the "?" Macro Icon will show the icon for the next spell to be cast.

*Note: You need to wait for an Auto Shot to go off before casting each Steady Shot to maximize your DPS. This is not a spammable macro.


---------------------------------------------------------------------------------------------------------------------------------------------


/castsequence reset=120/target/combat/ctrl/alt Hunter’s Mark,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot,Aimed Shot
/petattack


What it does?
To start off a battle.
Will use Hunter’s Mark on target on 1st click, then cast Aimed Shot on 2nd click.
The rest of “reset=120/target/combat/ctrl/alt” is to keep the button only for Aimed Shot after the Hunter’s Mark has already been used until you switch target, get out of combat, or use the modifier keys of ctrl or alt.
The last line "/petattack" is optional, depending on your style.
Select the "?" macro icon for better use.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [target=focus,help][help][target=pet,exists,nodead] Misdirection


What it does?
Set the focus target using the Hunter's Mark / Focus Target macro, in this case the Main Tank; then use this macro just before pulling to cast Misdirection on your focus target without losing your target.

This will misdirect to your focus target, if that is friendly.
If not, it will cast on your selected target if it is friendly.
If it isn't or you don't have a target selected, it will misdirect on your pet.
That way, the macro works as intended in any situation, without the need of pressing qualifier keys or choosing between different buttons.

---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [target="Tank"] Misdirection


What it does?
A macro that does almost the same thing, but doesn't use a focus is as follows. This will cast Misdirection on the tank without losing your target.
Just replace "Tank" with your tank.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/focus [help]
/stopmacro [help]
/cast [target=focus,exists] Misdirection; [target=pet,exists] Misdirection


What it does?
Another useful macro combination for one-button misdirecting.
If you select a friendly target, it will make them the focus, otherwise it will cast misdirection on whatever the focus was.
If you haven't got a focus set, it will misdirect to your pet instead.

Usage:
1. Select tank and click macro button. This will set your tank as focus target. You only have to do this once, until you want to change the focus to a different player.
2. Select the mob that you want to pull (and misdirect).
3. Shoot away!


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/focus [help]
/script SendChatMessage ("You are now my FOCUS target","WHISPER",nil,UnitName("target"))
/stopmacro [help]
/y ~~Misdirecting on %f~~
/cast [target=focus,exists] Misdirection


What it does?
Variation on above macro.
This will whisper your tank every time you change focus targets; feel free to change the message to something witty.
This also includes a yell that will announce your misdirection on your focus target, to help prevent overlapping misdirection casts.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Rapid Fire
/cast Rapid Fire
/cast Berserking
/cast Aimed Shot


What it does?
For a fast, hard-hitting Aimed Shot when you need it.
You can also change the Berserking to another racial ability such as Blood Fury for Orcs.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [nomodifier] Serpent Sting; [modifier:shift] Viper Sting; [modifier:ctrl] Scorpid Sting; [modifier:alt] Tranquilizing Shot


What it does?
Put most of your stings on a single key.
Use the "?" macro icon and it will show which one is up when you hold down a key.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast Distracting Shot
/stopcasting
/stopattack


What it does?
Cast distracting shot, then stop attacking.
This can also be modified for use on Silencing Shot trap pulls by changing the spell name.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/castsequence reset=30 Mana Tap, Viper Sting, Viper Sting


What it does?
Using a combination of the Blood Elf racial Mana Tap and the standard Viper Sting.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Silencing Shot
/stopcasting
/cast Silencing Shot


OR


#showtooltip Silencing Shot
/cast [target=mouseover, harm][harm] Silencing Shot


What it does?
Just a easy macro to stop casting your Aimed/Steady Shot or any other shot and fire your Silencing Shot.
Second one: just mouseover your intended target without losing your current target.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/castsequence [modifier:ctrl] reset=target/combat Concussive Shot, Steady Shot; Wing Clip


What it does?
*The #showtooltip is optional, making this a one-liner. It is recommended to use the "?" macro icon when creating this macro.

If you hold ctrl while activating this macro, it will start a sequence of Concussive Shot followed by Steady Shot (highest damage for this shot).
Elsewise (no modifier while activating) it will just Wing Clip.
If you change targets or your target dies, the sequence (ctrl) will reset.
If you Steady Shot, the sequence also resets.
There is no need to keep holding ctrl for the sequence.
Wing Clip should not break the sequence either (this can be a problem, depending).

Melee



#showtooltip Raptor Strike
/cast Blood Fury
/cast Raptor Strike
/cast Wing Clip
/stopcasting


What it does?
Racial Ability (ex. Blood Fury) + Raptor Strike + Wing Clip
This is a very simple macro that queues a racial ability such as Blood Fury for Orc/Berserking for Trolls, and Raptor Strike for the next normal melee swing and uses Wing Clip.
The stopcasting is used to cancel the Raptor Strike effect if the Wing Clip isn't done.
If your Raptor Strike is on cooldown, Wing Clip can be used alone.
Although this macro contains two skills, it works because one attacks instantly and the other attacks on the next melee swing.
Select the "?" macro icon for better use.


---------------------------------------------------------------------------------------------------------------------------------------------


/castsequence [nopet] Call Pet; [nocombat] Mend Pet; reset=combat/target/10 Wing Clip, Raptor Strike, Raptor Strike, Raptor Strike


What it does?
With one button you can now Mend your pet or spam Wing Clip and Raptor Strike.
Set the time in /target/10 to whatever you like, and append as many Raptor Strikes as you like.
Raptor Strike has been added more than once to ensure it is cast before the timer is up.


---------------------------------------------------------------------------------------------------------------------------------------------


#Show Raptor Strike
/petAttack
/startattack
/script UIErrorsFrame:Hide()
/castrandom wing clip, Raptor Strike, Wing Clip
/cast kill command
/cast Mongoose Bite
/script UIErrorsFrame:Clear()
/script UIErrorsFrame


What it does?
The following macro forces your pet to attack the target you are attacking, uses wingclip when it is present, but it gives priority to Raptor Strike over most other talents.
It will cast Mongoose bite if it procs, and if you crit, it will cast Kill Command if your pet is near a target. You can remove the pet attack commands by deleting the second and third line of the macro.
The "script" commands hide the UI's error text when abilities are not ready.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast Raptor Strike
/cast Mongoose Bite


What it does?
One button for RS / MB

Traps



#showtooltip [modifier:alt] Frost Trap; Freezing Trap
/stopcasting
/stopattack
/cast [modifier:alt] Frost Trap; Freezing Trap


What it does?
Cut down on the number of buttons you have dedicated to traps.
The stopcasting & stopattack will help keep you from breaking your own traps.
You can also use Immolation/Explosive.
Use the "?" macro icon.


---------------------------------------------------------------------------------------------------------------------------------------------


/stopcasting
/stopattack
/cast [btn:1,nomod]Explosive Trap;[mod:shift]Frost Trap;[mod:ctrl,nomod:alt]Snake Trap;[mod:alt,nomod:ctrl]Freezing Trap;[mod:alt,mod:ctrl]Immolation Trap;


What it does?
This will allow you to choose between several traps to place while in combat to save space.


---------------------------------------------------------------------------------------------------------------------------------------------


/script PetWait()
/script PetPassiveMode()
/script ClearTarget
/cast Feign Death
/cast Freezing Trap(Rank 3)


What it does?
Just hit this one button twice - once to feign death, and the second time to lay a trap.

In order to lay the trap, you must be out of combat mode.
And to exit combat mode most successfully, your pet must not be attacking anything, and your target must be cleared.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast Scatter Shot
/script ClearTarget()
/cast Feign Death
/cast Freezing Trap(Rank #)
/cast Aspect of the Cheetah


What it does?
Easy xplained: you get ambushed and you want to get out? Click it times and get the hell out :p

Tracks



/castsequence [nocombat] reset=10 Find Minerals, Find Herbs, Track Beasts, Track Demons, Track Dragonkin, Track Elementals, Track Giants, Track Hidden, Track Humanoids, Track Undead


What it does?
The reset=10 allows you to wait 10 seconds between using the macro to only change between minerals and herbs.
You can shorten or lengthen it as you see fit.
The rest are in alphabetical order.


---------------------------------------------------------------------------------------------------------------------------------------------


/castsequence [nocombat,help] Find Herbs, Find Minerals
/castsequence [nocombat,noexists] Find Herbs, Find Minerals
/castsequence [nocombat,harm] Track Beasts, Track Demons, Track Dragonkin, Track Elementals, Track Giants, Track Hidden, Track Humanoids, Track Undead


What it does?
The alternative cycles the gathering skills if you have a friendly target (yourself/pet/party member/NPC) or no target, and the combat skills if you have a hostile target.

Miscellaneous



/assist [target=focus, exists]
/cast [nocombat] attack;
/startattack [combat];


What it does?
The Assist Focus macro is setup to assist and attack the target of the focus target; in this case, it is the main tank or main assist.
You can use the Hunter's Mark / Focus Target macro to easily set your focus target; then use this macro to target his target from then on.
So it is a main tank assist macro centered around the focus target.


---------------------------------------------------------------------------------------------------------------------------------------------


/assist [target=focus,exists]focus; [target=pet,exists]pet
/startattack [combat];
/cast Hunter's Mark


What it does?
This one utilizes the above macro, but adds a fail safe where focus isn't set and assists your pet.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [button:2] Aspect of the Pack; Aspect of the Cheetah


What it does?
Switches between AotP and AotC with one mouseclick.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [button:2] Aspect of the Pack; [button:3] Aspect of the Beast; Aspect of the Cheetah


What it does?
Switches between AotP, AotB and AotC with one mouseclick.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [button:2] Aspect of the Viper; [button:3] Aspect of the Monkey; Aspect of the Hawk


What it does?
Left-click to cast AotH; middle click to cast AotM; right-click to cast AotV.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Hunter's Mark
/cast [harm] Hunter's Mark;
/focus [help]


What it does?
The Hunter's Mark macro will set the focus target if the target is friendly or it will cast Hunter's Mark if the target is hostile.
This macro is handy along with the Misdirection macro to set the recipient of aggro, typically the main tank, and with the Assist Focus macro to set the main assist.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast Hunter's Mark
/petattack


What it does?
Mark your current target and send your pet to attack while keeping the Hunter's Mark icon and tooltip.
If you don't want to manually find the Hunter's Mark icon in the macro icon selection window, simply select the question mark icon, and the macro will automatically change it to the Hunter's Mark icon for you.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Hunter's Mark
/cast Auto Shot
/cast Hunter's Mark
/petattack


What it does?
A simpler form, without the tooltips, but adding Auto Shot also works properly.
Auto Shot is an effect, and is not subject to the Global Cooldown that affects Spells like Hunter's Mark.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Hunter's Mark
/cast [button:2] Hunter's Mark; Hunter's Mark
/stopmacro [button:2]
/petattack


What it does?
Allows you to add Hunter's Mark to a mob without sending in your pet.
All you have to do is right-click the button to cast only the Hunter's Mark.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Hunter's Mark
/dismount [target=player, mounted]
/cast [pet, harm, nodead] Hunter's Mark;
/petattack [pet, harm, nodead]


What it does?
Lets you dismount, and then if pressed again it will mark the target and send the pet in to attack.
If your not mounted in the first place then it will just mark the target and send the pet in to attack.
The [pet, harm] conditions on the /cast and /petattack are there to check that your pet exists, and that the target is hostile.
If your thinking of removing the [pet] condition you'll run into the following problem: while your mounted you'll still mark the target, but the pet can't attack because your pet is still nonexistent.
So then you would have to waste mana re-marking the target just to use the /petattack portion of the macro.
[Harm] and [nodead] conditions are solely there to remove error messages.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [nocombat,noactionbar:1] Aspect of the Hawk; [combat,noactionbar:2] Aspect of the Monkey
/swapactionbar 1 2


What it does?
Select the "?" macro icon.
The following macro will swap between a melee and a range action bar while casting Aspect of the Monkey for melee or Aspect of the Hawk for range.
Additionally, it’ll keep you in the appropriate aspect even if you accidentally press the button again.
So when you are in hand-to-hand (melee) combat, it’ll keep you at the Aspect of the Monkey no matter how many times you press the button.
In this example, the melee spells are on action bar 2 and the range spells on action bar 1.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [noactionbar:1, nomodifier:alt] Aspect of the Hawk; [noactionbar:2, nomodifier:alt] Aspect of the Monkey; [modifier:alt] Aspect of the Viper
/swapactionbar [nomodifier:alt] 1 2


What it does?
Same as above AND hold down alt to cast Aspect of the Viper without switching actionbars.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Reins of the Swift Stormsaber
/cast [nomounted] Aspect of the Monkey
/use [nomounted] Reins of the Swift Stormsaber
/cast [mounted] Aspect of the Hawk


What it does?
To decrease the chances that you get knocked off your mount when attacked, you can set up a macro that will automatically cast Aspect of the Monkey when you mount.
Replace mount name with the one you are using ofcourse.

If you are not mounted, clicking the button casts Aspect of the Monkey and then summons your mount.
If you are mounted, clicking the same button causes you to dismount and then cast Aspect of the Hawk.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Ebon Griffon
/cast [button:1] Aspect of the Monkey
/stopcasting
/use Ebon Griffon
/use [button:2] Ebon Griffon


What it does?
Same as above.
With the option of right clicking to keep Aspect of the Monkey.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip Ebon Gryphon
/cast Aspect of the Monkey
/stopcasting
/use [button:2] Ebon Gryphon; Reins of the Swift Stormsaber
/cast [mounted] Aspect of the Hawk


What it does?
Left Button for Swift Stormsaber Mount and Right Button for Ebon Gryphon Mount (Adjust mount names accordingly to your specific mounts).
Casts AotM right before you mount (Less chance of getting dismounted).
If you are mounted, casts AotH and dismounts you.


---------------------------------------------------------------------------------------------------------------------------------------------


/script UIErrorsFrame:Hide()
/cast Kill Command
/stopcasting
/cast Mongoose Bite


What it does?
This will cast whichever is currently available (or both if both are), so you can just hit it reflexively when the yellow text pops up (if you have that option in the built-in floating combat text turned on) without having to read it.


---------------------------------------------------------------------------------------------------------------------------------------------


/castsequence reset=30 Feign Death, Disengage, Disengage, Disengage, Disengage, Disengage, Disengage


What it does?
Casts Feign Death on the first press, then Disengage on subsequent presses until your FD cooldown is up. (Remember, though: Disengage only works in melee range.)

*Note that the above macro will not work exactly as advertised.
The macro will reset back to the beginning only after you haven't clicked on the macro for 30 seconds. So, if you were to click it once (and Feign Death), and then again in 10 seconds (and Disengage), and again in 25 seconds (you would disengage, NOT feign death even though FD has cooled down).
Use with care.


---------------------------------------------------------------------------------------------------------------------------------------------


/assist [target=focus, modifier:alt, exists]
/assist [target=pet, modifier:ctrl]
/cast hunter's mark
/petattack [modifier:shift]
/targetlasttarget [modifier:Shift]
/stopmacro [modifier:Shift]
/cast [harm] Auto Shot;
/stopmacro [modifier:ctrl]
/petattack


What it does?
== Focus main tank ==
Ok {Button} Hit it normally
1.Cast hunter’s mark
2.Pet Attacks
3.Starts auto shoot
{Button & Shift}
1.Cast hunter’s mark
2.Pet Attacks
3.Target Last Target
{Button & Alt}
1.Assist Focus
2.Cast hunter’s mark
3.Pet Attacks
4.Starts auto shoot
{Button & Ctrl}
1.Assist Pet
2.Cast hunter’s mark
3.Starts auto shoot


-----------------------------------------------------------------------------------------------------------------------------------

More Miscellaneous + Farming




/cast [nocombat,nomounted]Aspect of the Viper
/use [nocombat,nomounted,nomodifier,nobutton:2,flyable]<flying mount>;[nocombat,nomounted]<land mount>
/dismount [mounted]
/cast [nocombat]Aspect of the Hawk


What it does?
1. If mounted, dismounts.
2. If mounted and out of combat, dismounts and casts Aspect of the Hawk.
3. If not mounted and out of combat, casts Aspect of the Viper, then attempts to mount in a flyable zone with your flying mount.
Unless you press a modifier key, right click it, or are in an unflyable zone, in which case you will mount your land mount.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [nomodifier]Aspect of the Cheetah; [modifier] Aspect of the Pack


What it does?
Will cast Apect of the Cheetah on normal click and Aspect of the Pack on shift-, alt-, or ctrl-click.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [btn:1,nomod]Aspect of the Hawk;[mod:shift]Aspect of the Pack;[mod:ctrl,nomod:alt]Aspect of the Cheetah;[mod:alt,nomod:ctrl]Aspect of the Wild;[mod:alt,mod:ctrl]Aspect of the Monkey;


What it does?
Saves space for the various Aspects, edit as it fits your style of play you need.
Only 5 will fit.


---------------------------------------------------------------------------------------------------------------------------------------------


/cast [harm,nodead,nocombat]Dash
/cast [harm,nodead]Hunter's Mark
/petattack [harm,nodead]
/startattack [harm,nodead,combat]
/stopmacro [harm,nodead]
/assist [target=pet]
/targetenemy [noexists]


What it does?
Keep your pet on defensive or Aggressive, this macro behaves like this:
1. If I have a target and am out of combat: cast Dash <or another pet speed increase move> cast Hunter's Mark and make pet attack my target.
2. If I have a target and am in combat: do everything in '1' and start attack.
3. If I have a pet and my target is dead or I do not have a target: grab my pets current target.
4. If neither I or my pet have a target, find an enemy target nearby.

Strictly PvE Macro; pressing this macro twice after killing one target will obviously grab the next in pet aggro to kill.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/dismount
/cast [combat]Arcane Shot;Arcane Shot(Rank 1)
/petattack


What it does?
Easy tagging of high profile farming mobs (i.e. Elementals in Nagrand)
Dismounts immediately and shoots rank 1 arcane shot...
least aggro hunter dps instant cast


---------------------------------------------------------------------------------------------------------------------------------------------


/petattack [target=target,exists]
/cast Mend Pet
/stopcasting
/use [button:1] (water)
/use [button:2] (water)
/use [button:2] (food)


What it does?
You can grind away while drinking.
Choose enemy and push the leftclick
1.mend pet
2.send it to bite someone
3.start drink
nochoose enemy and push the leftclick
1.mend pet
3.start drink
nochoose enemy and push the rightclick
1.mend pet
3.start drink & eat

*Note: not recommend for choose enemy and rightclick.
because its doesn't heal you while in combat like drink does.


---------------------------------------------------------------------------------------------------------------------------------------------


/petattack
/cast Auto Shot
/cast [nocombat] Hunter's Mark
/castsequence [combat] Feign Death, Arcane Shot


What it does?
When you press this macro:
1. Your pet will automatically target and pursue.(/petattack)
2. Auto Shot will be enabled against your target.
3. If you are not engaged(You shouldn't), Hunter's Mark will be cast against that enemy.

Additionally, pressing this macro while in-combat will:
1. Feign Death (Used when you pull aggro from your pet, obviously)
2. A second press will cause you to cast Arcane Shot, and more importantly, resume the Auto Shooting.

*Note: This macro is designed to be used against one NPC at a time.


---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/castsequence [nomodifier,button:1] reset=combat/target Hunter's Mark, Aimed Shot, Concussive Shot, Arcane Shot, Arcane Shot
/cast [modifier:shift] Serpent Sting; [modifier:ctrl] Scorpid Sting; Viper Sting
/stopmacro [button:1]
/petattack


What it does?
This macro casts Hunter's Mark to begin with.
Click again to cast Aimed Shot, Concussive Shot, Arcane shot and another Arcane shot.
Auto shot is not included because the Blizzard UI will cast auto shot automatically.
Right mousebutton will command your pet to attack.
Hold SHIFT and leftclick to cast Serpent Sting. Hold CTRL to cast Scorpid Sting and ALT to cast Viper Sting.

The macro will reset when changing or killing target.

Reported for sticky. Nice macros :D

Really great and well written, especially like your "what does it do", makes it easier to understand purpose and such.
Maybe a bit long list tho lol :-)
I'm picking up 1 or 2 of these for sure

Hmm, thinking if i can combine the Mend pet castsequence macro with the Revive/Call/Mend pet one...

gief totemslaying macros =(

First of, great guide!

But secondly i need some help, i SUCK at macroing

i was wondering how u modify the:

/cast [harm,nodead,nocombat]Dash
/cast [harm,nodead]Hunter's Mark
/petattack [harm,nodead]
/startattack [harm,nodead,combat]
/stopmacro [harm,nodead]
/assist [target=pet]
/targetenemy [noexists]

to start starts a shootsequence with serpentsting, then a normal auto/steady rotation instead of the normal autoshoot spree?

Any ideas would be welcome!

Thanks in advance

True.
But i reposted those here, because some people are too lazy or don't even know where to check for macro's.
Instead of that, they keep spamming the forums.
And I will also keep creating macro's myself. And being on the hunt for others as well.
But atm I'm too busy working on a new interface to put up on curse.com :)

---

Q u o t e:
First of, great guide!

But secondly i need some help, i SUCK at macroing

i was wondering how u modify the:

/cast [harm,nodead,nocombat]Dash
/cast [harm,nodead]Hunter's Mark
/petattack [harm,nodead]
/startattack [harm,nodead,combat]
/stopmacro [harm,nodead]
/assist [target=pet]
/targetenemy [noexists]

to start starts a shootsequence with serpentsting, then a normal auto/steady rotation instead of the normal autoshoot spree?

Any ideas would be welcome!

Thanks in advance

---

This should be the one that starts of with serpent sting and then continues with Auto and steady shot:

/castsequence [nocombat] Serpent Sting; [combat] reset=6 !Auto Shot, Steady Shot



Didn't try it out yet myself, as i'm not logged atm. Will do tomorrow :)

---

Q u o t e:
Pet related:

---------------------------------------------------------------------------------------------------------------------------------------------


#showtooltip
/cast [nopet,modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; [combat][modifier]Mend Pet
/stopmacro [combat]
#showtooltip Feed Pet
/cast Feed Pet
/use <food item>


What it does?
1. This macro calls your pet if he's not out.
2. Revives him if he's dead.
3. Heals him during combat.
4. Feeds him out of combat.
Since the macro system can't tell whether your pet is alive if his corpse isn't around, holding any modifier when you have no pet out will cast Revive Pet. Also, holding any modifier key when your pet is out will heal him instead of feeding.

---

I wanted to reverse this, so Feed Pet was on the modifier, and the following macro solved it for me:

#showtooltip
/cast [nopet,modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; [modifier] Feed Pet; Mend Pet
/use [modifier] <pet food name>

---

Q u o t e:
gief totemslaying macros =(

---

/petattack
/petattack [target=Searing Totem]
/petattack [target=Wrath of Air Totem]
/petattack [target=Grounding Totem]
/petattack [target=Windfury Totem]
/petattack [target=Mana Spring Totem]


This macro is used by warlocks as well (mine used to use it).
The macro works from below to above (so first Mana Spring Totem, then Windfury etc...)

---

Q u o t e:


I wanted to reverse this, so Feed Pet was on the modifier, and the following macro solved it for me:

#showtooltip
/cast [nopet,modifier] Revive Pet; [target=pet,dead] Revive Pet; [nopet] Call Pet; [modifier] Feed Pet; Mend Pet
/use [modifier] <pet food name>

---

Added to the list. Thanks for sharing :)

hehe thanks :-)

Played around with it a bit more, cos i wanted it to show the pet food instead of Feed Pet, since that's more useful info, and this one does the trick:

#showtooltip [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [mod] <Pet Food Name>; Mend Pet
/cast [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [modifier] Feed Pet; Mend Pet
/use [modifier] <Pet Food Name>


I shortened all the "modifier" to "mod" and removed the extra Revive Pet, cos for a while there i was going over the 255 letter limit.

It's damn perfect to me now! :-)

---

Q u o t e:
hehe thanks :-)

Played around with it a bit more, cos i wanted it to show the pet food instead of Feed Pet, since that's more useful info, and this one does the trick:

#showtooltip [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [mod] <Pet Food Name>; Mend Pet
/cast [nopet,mod][target=pet,dead] Revive Pet; [nopet] Call Pet; [modifier] Feed Pet; Mend Pet
/use [modifier] <Pet Food Name>


I shortened all the "modifier" to "mod" and removed the extra Revive Pet, cos for a while there i was going over the 255 letter limit.

It's damn perfect to me now! :-)

---

Good to see that people actually try some stuff out theirselves now.

This might be a lower level character of me, but got some "biggies" too. And after playing so long on wow you start seeing more then just questing.
It gets you thinking how to improve your playstyle. Either addons, macro's or a customized interface help in that process :)